Создание библиотек подпрограмм в Turbo Pascal

А.П. Шестаков. Создание библиотек подпрограмм в Turbo Pascal

Стандартный язык Pascal не располагает средствами разработки и поддержки библиотек программиста (в отличие, скажем, от языка Fortran и других языков программирования высокого уровня), которые компилируются отдельно и в дальнейшем могут быть использованы как самим разработчиком, так и другими. Если программист имеет достаточно большие наработки, и те или иные подпрограммы могут быть использованы при написании новых приложений, то приходится эти подпрограммы целиком включать в новый текст.

В Turbo Pascal это ограничение преодолевается за счет, во-первых, введения внешних процедур, во-вторых, разработки и использования модулей. В настоящей публикации на примерах рассмотрим работу с теми и другими программными единицами.

Начнем с внешних подпрограмм.

Такой механизм предусматривает, что исходный текст каждой процедуры или функции хранится в отдельном файле и при необходимости с помощью специальной директивы компилятора включается в текст создаваемой программы.

Покажем это на примере задач целочисленной арифметики, где аргументы, результаты и промежуточные величины являются целыми (Integer, Word, LongInt и т.д.). Вот несколько таких задач.

1. Дано натуральное число n. Найти сумму первой и последней цифры этого числа.

2. Дано натуральное число n. Переставить местами первую и последнюю цифры этого числа.

3. Дано натуральное число n. Дописать к нему цифру k в конец и в начало (если это возможно, т.е. результат не выйдет за диапазон допустимых значений), или сообщить о невозможности выполнения операции.

4. Найти наибольшую цифру в записи данного натурального числа.

5. Дано натуральное число n. Переставить его цифры так, чтобы образовалось максимальное число, записанное теми же цифрами.

При решении каждой из этих задач может быть использована функция, возвращающая количество цифр в записи натурального числа.

Вот возможный вариант такой функции:

Function Digits(N : LongInt) : Byte;
Var Kol : Byte;
Begin
    Kol := 0;
    While N <> 0 Do Begin Kol := Kol + 1; N := N Div 10 End;
    Digits := Kol
End;

Сохраним этот текст в файле с расширением .inc (это расширение внешних подпрограмм в Turbo Pascal), например, digits.inc.

Еще необходима функция возведения натурального числа в натуральную степень.

Function Power(A, N : LongInt) : LongInt; {файл power.inc}
Var I, St : LongInt;
Begin
    St := 1;
    For I := 1 To N Do St := St * A;
    Power := St
End;

Попробуем использовать функции при решении задачи номер один.

Program Example1;
Var N, S : LongInt;
{$I digits.inc} {подключаем внешнюю функцию digits.inc, 
возвращающую количество цифр в записи числа}
{$I power.inc} {внешняя функция, выполняющая возведение 
числа A в степень N}
Begin
    Write('Введите натуральное число: ');
    ReadLn(N);
{для определения последней цифры числа N берем остаток от деления 
этого числа на 10, а для определения первой делим N на 10 в 
степени на единицу меньшую, чем количество  цифр в записи 
числа (нумерация разрядов начинается с 0)}
    S := N Mod 10 + N Div Power(10, Digits(N) - 1);
    WriteLn('Искомая сумма: ', S)
End.

Внешние процедуры создаются и внедряются в использующие их программы аналогично функциям, и мы не будем подробно на этом останавливаться.

Далее речь пойдет о модулях: их структуре, разработке, компиляции и использовании.

Модуль — это набор ресурсов (функций, процедур, констант, переменных, типов и т.д.), разрабатываемых и хранимых независимо от использующих их программ. В отличие от внешних подпрограмм модуль может содержать достаточно большой набор процедур и функций, а также других ресурсов для разработки программ. Обычно каждый модуль содержит логически связанные между собой программные ресурсы.

В основе идеи модульности лежат принципы структурного программирования. Существуют стандартные модули Turbo Pascal, которые обычно описываются в литературе по данному языку.

Модуль имеет следующую структуру:

Unit <имя модуля>; {заголовок модуля}
Interface
    {интерфейсная часть}
Implementation
    {раздел реализации}
Begin
    {раздел инициализации модуля}
End.

После служебного слова Unit записывается имя модуля, которое (для удобства дальнейших действий) должно совпадать с именем файла, содержащего данный модуль. Поэтому (как принято в MS DOS) имя не должно содержать более 8 символов.

В разделе Interface объявляются все ресурсы, которые будут в дальнейшем доступны программисту при подключении модуля. Для подпрограмм здесь указывается лишь полный заголовок.

В разделе Implementation реализуются все подпрограммы, которые были ранее объявлены. Кроме того, здесь могут содержаться свои константы, переменные, типы, подпрограммы и т.д., которые носят вспомогательный характер и используются для написания основных подпрограмм. В отличие от ресурсов, объявленных в разделе Interface, все, что дополнительно объявляется в Implementation, уже не будет доступно при подключении модуля. При написании основных подпрограмм достаточно указать их имя (т.е. не нужно полностью переписывать весь заголовок), а затем записать тело подпрограммы.

Наконец, раздел инициализации (который часто отсутствует) содержит операторы, которые должны быть выполнены сразу же после запуска программы, использующей модуль.

Приведем пример разработки и использования модуля. Поскольку рассмотренная ниже задача достаточно элементарна, ограничимся листингом программы с подробными комментариями.

Задача. Реализовать в виде модуля набор подпрограмм для выполнения следующих операций над обыкновенными дробями вида P/Q (P — целое, Q — натуральное): 1) сложение; 2) вычитание; 3) умножение; 4) деление; 5) сокращение дроби; 6) возведение дроби в степень N (N — натуральное); 7) функции, реализующие операции отношения (равно, не равно, больше или равно, меньше или равно, больше, меньше).

Дробь представить следующим типом:

      Type Frac = Record
		      P : Integer;
		      Q : 1.. High(LongInt)
		     End;

Используя этот модуль, решить задачи:

1. Дан массив A — массив обыкновенных дробей. Найти сумму всех дробей, ответ представить в виде несократимой дроби. Вычислить среднее арифметическое всех дробей, ответ представить в виде несократимой дроби.

2. Дан массив A — массив обыкновенных дробей. Отсортировать его в порядке возрастания.

Unit Droby;
Interface
      Type
	     Natur = 1..High(LongInt);
	     Frac = Record
		      P : LongInt; {Числитель дроби}
		      Q : Natur {Знаменатель дроби}
		     End;
Procedure Sokr(Var A : Frac);
Procedure Summa(A, B : Frac; Var C : Frac);
Procedure Raznost(A, B : Frac; Var C : Frac);
Procedure Proizvedenie(A, B : Frac; Var C : Frac);
Procedure Chastnoe(A, B : Frac; Var C : Frac);
Procedure Stepen(A : Frac; N : Natur; Var C : Frac);
Function Menshe(A, B : Frac) : Boolean;
Function Bolshe(A, B : Frac) : Boolean;
Function Ravno(A, B : Frac) : Boolean;
Function MensheRavno(A, B : Frac) : Boolean;
Function BolsheRavno(A, B : Frac) : Boolean;
Function NeRavno(A, B : Frac) : Boolean;
{Раздел реализации модуля}
Implementation
{Наибольший общий делитель двух чисел - вспомогательная функция, 
ранее не объявленная}
Function NodEvklid(A, B : Natur) : Natur;
Begin
  While A <> B Do
    If A > B Then
	      If A Mod B <> 0 Then A := A Mod B Else A := B
	     Else
	      If B Mod A <> 0 Then B := B Mod A Else B := A;
    NodEvklid := A
End;
Procedure Sokr; {Сокращение дроби}
Var M, N : Natur;
Begin
   If A.P <> 0 Then
   Begin
	If A.P < 0 Then M := Abs(A.P)
		   Else M := A.P; 
{Совмещение типов, т.к. A.P - LongInt}
	N := NodEvklid(M, A.Q); 	
A.P := A.P Div N; A.Q := A.Q Div N
   End
End;
Procedure Summa; {Сумма дробей}
Begin
   {Знаменатель дроби}  C.Q := (A.Q * B.Q) Div NodEvklid(A.Q, B.Q);
   {Числитель дроби}      C.P := A.P * C.Q Div A.Q + B.P * C.Q Div B.Q;
   Sokr(C)
End;
Procedure Raznost; {Разность дробей}
Begin
   {Знаменатель дроби} C.Q := (A.Q * B.Q) Div NodEvklid(A.Q, B.Q);
   {Числитель дроби}     C.P := A.P * C.Q Div A.Q - B.P * C.Q Div B.Q;
   Sokr(C)
End;
Procedure Proizvedenie;
Begin
   {Знаменатель дроби} C.Q := A.Q * B.Q;
   {Числитель дроби} C.P := A.P * B.P;
   Sokr(C)
End;
Procedure Chastnoe;
Begin
   {Знаменатель дроби}  C.Q := A.Q * B.P;
   {Числитель дроби}      C.P := A.P * B.Q;
   Sokr(C)
End;
Procedure Stepen; {Степень}
Var I : Natur;
Begin
    C.Q := 1; C.P := 1; Sokr(A);
    For I := 1 To N Do Proizvedenie(A, C, C)
End;
Function Menshe;
Begin Menshe := A.P * B.Q < A.Q * B.P End;
Function Bolshe;
Begin  Bolshe := A.P * B.Q > A.Q * B.P End;
Function Ravno;
Begin Ravno := A.P * B.Q = A.Q * B.P End;
Function BolsheRavno;
Begin BolsheRavno := Bolshe(A, B) Or Ravno(A, B) End;
Function MensheRavno;
Begin MensheRavno := Menshe(A, B) Or Ravno(A, B) End;
Function NeRavno;
Begin  NeRavno := Not Ravno(A, B) End;
{Раздел инициализации модуля}
Begin
End.

Дадим некоторые рекомендации по разработке модулей:

1) спроектировать модуль, т.е. выделить основные и вспомогательные подпрограммы, другие ресурсы;

2) каждую подпрограмму целесообразно отладить отдельно, после чего «вклеить» в текст модуля.

Сохраним текст разработанной программы в файле DROBY.PAS и откомпилируем наш модуль. Для этого можно воспользоваться внешним компилятором, поставляемым вместе с Turbo Pascal. Команда будет выглядеть так: TPC DROBY.PAS. Если в тексте нет синтаксических ошибок, получим файл DROBY.TPU, иначе будет соответствующее сообщение с указанием строки, содержащей ошибку. Другой способ компиляции модуля — в среде программирования Turbo Pascal выбрать в пункте меню Run подпункты Make или Build (при этом должна быть включена компиляция на диск).

Теперь можно подключить модуль к программе, где планируется его использование.

Для примера решим задачу суммирования массива дробей.

Program Sum;
Uses Droby;
Var A : Array[1..100] Of Frac;
    I, N : Integer;
    S : Frac;
Begin
    Write('Введите количество элементов массива: ');
    ReadLn(N);
    S.P := 0; S.Q := 1; {Первоначально сумма равна нулю}
    For I := 1 To N Do {Вводим и суммируем дроби}
    Begin
	Write('Введите числитель ', I, '-й дроби: '); ReadLn(A[I].P);
	Write('Введите знаменатель ', I, '-й дроби: '); ReadLn(A[I].Q);
	Summa(A[I], S, S);
    End;
    WriteLn('Ответ: ', S.P, '/', S.Q)
End.

Вторую задачу предлагаем решить читателю самостоятельно.

Как видно из примера, для подключения модуля используется служебное слово USES, после чего указывается имя модуля и происходит это сразу же после заголовка программы. Если необходимо подключить несколько модулей, они перечисляются через запятую.

При использовании ресурсов модуля совсем не нужно знать, как работают его подпрограммы. Достаточно обладать информацией, как выглядят их заголовки и какое действие эти подпрограммы выполняют. По такому принципу осуществляется работа со всеми стандартными модулями. Поэтому, если программист разрабатывает модули не только для личного пользования, ему необходимо сделать полное описание всех доступных при подключении ресурсов. В таком случае возможна полноценная работа с таким продуктом.

Ещё несколько слов о видимости объектов модуля. Если в программе, использующей модуль, имеются идентификаторы, совпадающие с точностью до символа с идентификаторами модуля, то они «перекрывают» соответствующие ресурсы модуля. Тем не менее, даже в такой ситуации доступ к этим ресурсам модуля может быть получен таким образом: <имя модуля>.<имя ресурса>.

В заключение приведем набор заданий, позволяющих получить определенные навыки в разработке модулей.

I. Реализовать в виде модуля набор подпрограмм для выполнения следующих операций над комплексными числами: 1) сложение; 2) вычитание; 3) умножение; 4) деление; 5) вычисление модуля комплексного числа; 6) возведение комплексного числа в степень n (n — натуральное).

Комплексное число представить следующим типом:

      Type Complex = Record
                     R, M : Real; {действительная и мнимая часть числа}
		End;

Используя этот модуль, решить задачи:

1. Дан массив A — массив комплексных чисел. Получить массив C, элементами которого будут модули сумм рядом стоящих комплексных чисел.

2. Дан массив A[M] — массив комплексных чисел. Получить матрицу B[N, M], каждая строка которой получается возведением в степень, равную номеру этой строки, соответствующих элементов данного массива A.

II. Реализовать в виде модуля набор подпрограмм для выполнения следующих операций с квадратными матрицами: 1) сложение двух матриц; 2) умножение одной матрицы на другую; 3) нахождение транспонированной матрицы; 4) вычисление определителя матрицы.

Матрицу описать следующим образом:

      Const NMax = 10;
      Type Matrica = Array [1..NMax, 1..Nmax] Of Real;

Используя этот модуль, решить следующие задачи:

1. Решить систему линейных уравнений N-го порядка (2<=N<=10) методом Крамера.

2. Задан массив величин типа Matrica. Отсортировать этот массив в порядке возрастания значений определителей матриц.

III. Реализовать в виде модуля набор подпрограмм для выполнения следующих операций над векторами на плоскости: 1) сложение; 2) вычитание; 3) скалярное умножение векторов; 4) умножение вектора на число; 5) длина вектора.

Вектор представить следующим типом:

Type Vector = Record X, Y : Real End;

Используя этот модуль, решить задачи:

1. Дан массив A — массив векторов. Отсортировать его в порядке убывания длин векторов.

2. С помощью датчика случайных чисел сгенерировать 2N целых чисел. N пар этих чисел задают N точек координатной плоскости. Вывести номера тройки точек, которые являются координатами вершин треугольника с наибольшим углом.

IV. Реализовать в виде модуля набор подпрограмм для выполнения следующих операций над натуральными числами в P-ичной системе счисления (2<=P<=9): 1) сложение; 2) вычитание; 3) умножение; 4) деление; 5) перевод из десятичной системы счисления в P-ичную; 6) перевод из P-ичной системы счисления в десятичную; 7) логическая функция проверки правильности записи числа в P-ичной системе счисления; 8) функции, реализующие операции отношения (равно, не равно, больше или равно, меньше или равно, больше, меньше).

P-ичное число представить следующим типом:

Type Chislo = Array [1..64] Of 0..8;

Используя этот модуль, решить задачи:

1. Возвести число в степень (основание и показатель степени записаны в P-ичной системе счисления). Ответ выдать в P-ичной и десятичной системах счисления.

2. Дан массив A — массив чисел, записанных в P-ичной системе счисления. Отсортировать его в порядке убывания. Ответ выдать в P-ичной и десятичной системах счисления.

V. Реализовать в виде модуля набор подпрограмм для выполнения следующих операций над натуральными числами в шестнадцатеричной системе счисления: 1) сложение; 2) вычитание; 3) умножение; 4) деление; 5) перевод из двоичной системы счисления в шестнадцатеричную; 6) перевод из шестнадцатеричной системы счисления в десятичную; 7) функция проверки правильности записи числа в шестнадцатеричной системе счисления; 8) функции, реализующие операции отношения (равно, не равно, больше или равно, меньше или равно, больше, меньше).

Используя этот модуль, решить задачи:

1. Возвести число в степень (основание и показатель степени записаны в шестнадцатеричной системе счисления). Ответ выдать в шестнадцатеричной и десятичной системах счисления.

2. Дан массив A — массив чисел, записанных в шестнадцатеричной системе счисления. Отсортировать его в порядке убывания. Ответ выдать в шестнадцатеричной и десятичной системах счисления.

VI. Определим граф как набор точек, некоторые из которых соединены отрезками, подграф — граф, подмножество данного графа. Реализовать в виде модуля набор подпрограмм, определяющих: 1) число точек в графе; 2) число отрезков в графе; 3) число изолированных подграфов в графе (подграфов, не соединенных отрезками); 4) диаметр графа — длину максимальной незамкнутой линии в графе (длина каждого звена — единица); 5) граф — объединение двух графов; 6) подграф — пересечение двух графов; 7) подграф — дополнение данного графа до полного (графа с тем же количеством вершин, что и в заданном, и с линиями между любыми двумя вершинами); 8) число отрезков, выходящих из каждой вершины графа; 9) при запуске должны инициализироваться переменные: Full_Graph — полный граф с числом вершин NumberOfVertix, Null_Graph — граф без отрезков с числом вершин NumberOfVertix.

Граф представить как объект

Const NumberOfVertix = 50;
Type Graph = Array[1..NumberOfVertix, 1..NumberOfVertix] Of Boolean;

Используя модуль, решить задачу: найти все правильные графы из N вершин (граф правилен, если из всех вершин выходит равное количество отрезков).

VII. Реализовать в виде модуля набор подпрограмм для работы с длинными целыми числами (числами, выходящими за диапазон допустимых значений любого целого типа): 1) сложение; 2) вычитание; 3) умножение; 4) нахождение частного и остатка от деления одного числа на другое; 5) функции, реализующие операции отношения (равно, не равно, больше или равно, меньше или равно, больше, меньше).

Длинное число представить следующим типом:

		Type Tsifra = 0..9; Chislo = Array [1..1000] Of Tsifra;

Используя этот модуль, решить задачи:

1. Возвести число в степень (основание и показатель степени — длинные числа).

2. Дан массив длинных чисел. Упорядочить этот массив в порядке убывания.

VIII. Реализовать в виде модуля набор подпрограмм для выполнения операций с многочленами от одной переменной (первый многочлен степени m, второй — степени n): 1) сложение; 2) вычитание; 3) умножение; 4) деление с остатком; 5) операции отношения (равно, не равно); 6) возведение в натуральную степень k одного из многочленов; 7) вычисление производной от многочлена; 8) вычисление значения в точке x₀.

Многочлен представить следующим типом:

		Type Mnogochlen = Array [1..500] Of Integer;

Используя этот модуль, решить задачи:

1. Найти наибольший общий делитель многочленов P(x) и Q(x).

2. Вычислить: P^s(x)-Q^r(x) (s, r — натуральные).

IX*. Реализовать в виде модуля набор подпрограмм для работы с длинными действительными числами (числами, выходящими за диапазон допустимых значений любого действительных типа или не представленных в памяти ЭВМ): 1) сложение; 2) вычитание; 3) умножение; 4) нахождение частного от деления одного числа на другое с заданным количеством знаков после запятой; 5) функции, реализующие операции отношения (равно, не равно, больше или равно, меньше или равно, больше, меньше); 6) тригонометрические функции, где аргументом и значениями являются длинные действительные числа (указание: использовать разложение соответствующей функции в ряд).

Длинное действительное число представить следующим типом:

	Type Tsifra = 0..9; Chislo = Array [1..1000] Of Tsifra;
          LongReal = Record
                       Znak : 0..1; {0 - "плюс", 1 - "минус"}
                       Ts, Dr : Chislo {целая и дробная части}
                     End;

Используя этот модуль, решить задачи:

1. Возвести число в степень (основание — длинное действительное, показатель степени — длинное целое число).

2. Дан массив длинных действительных чисел. Упорядочить этот массив в порядке возрастания.